実技課題　　解答及び解説

実技課題　解答及び解説

　「マイコンによるアセンブリ言語を用いたモータ制御」

【プログラム例】

・リモコン側

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\* 訓練課題：リモコンプログラム　sousin.mar \*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.CPU 300HA

P7DR .EQU H'FFFFCE ; ﾎﾟｰﾄ7ﾃﾞｰﾀﾚｼﾞｽﾀ

PBDDR .EQU H'FFFFD4 ; ﾎﾟｰﾄBﾃﾞｰﾀﾃﾞｨﾚｸｼｮﾝﾚｼﾞｽﾀ

PBDR .EQU H'FFFFD6 ; ﾎﾟｰﾄBﾃﾞｰﾀﾚｼﾞｽﾀ

DIVCR .EQU H'FFFF5D ; 分周比ｺﾝﾄﾛｰﾙﾚｼﾞｽﾀ

TSTR .EQU H'FFFF60 ; ﾀｲﾏｽﾀｰﾄﾚｼﾞｽﾀ

STR0 .BEQU 0,TSTR ; ﾀｲﾏｽﾀｰﾄﾚｼﾞｽﾀのSTR0ﾋﾞｯﾄ

TCR0 .EQU H'FFFF64 ; ﾀｲﾏｺﾝﾄﾛｰﾙﾚｼﾞｽﾀ0

TCNT0 .EQU H'FFFF68 ; ﾀｲﾏｶｳﾝﾀ0(Wﾃﾞｰﾀ)

TSR0 .EQU H'FFFF67 ; ﾀｲﾏｽﾃｰﾀｽﾚｼﾞｽﾀ0

IMFA0 .BEQU 0,TSR0 ; ﾀｲﾏｽﾃｰﾀｽﾚｼﾞｽﾀ0のIMFAﾋﾞｯﾄ

GRA0 .EQU H'FFFF6A ; ｼﾞｪﾈﾗﾙﾚｼﾞｽﾀA0(Wﾃﾞｰﾀ)

TIER0 .EQU H'FFFF66 ; ﾀｲﾏｲﾝﾀﾗﾌﾟﾄｲﾈｰﾌﾞﾙﾚｼﾞｽﾀ0

IMIEA0 .BEQU 0,TIER0 ; ﾀｲﾏｲﾝﾀﾗﾌﾟﾄｲﾈｰﾌﾞﾙﾚｼﾞｽﾀ0のIMIEAﾋﾞｯﾄ

STR1 .BEQU 1,TSTR ; ﾀｲﾏｽﾀｰﾄﾚｼﾞｽﾀのSTR1ﾋﾞｯﾄ

TCR1 .EQU H'FFFF6E ; ﾀｲﾏｺﾝﾄﾛｰﾙﾚｼﾞｽﾀ1

TCNT1 .EQU H'FFFF72 ; ﾀｲﾏｶｳﾝﾀ1(Wﾃﾞｰﾀ)

TSR1 .EQU H'FFFF71 ; ﾀｲﾏｽﾃｰﾀｽﾚｼﾞｽﾀ1

IMFA1 .BEQU 0,TSR1 ; ﾀｲﾏｽﾃｰﾀｽﾚｼﾞｽﾀ1のIMFAﾋﾞｯﾄ

GRA1 .EQU H'FFFF74 ; ｼﾞｪﾈﾗﾙﾚｼﾞｽﾀA1(Wﾃﾞｰﾀ)

SCR .EQU H'FFFFBA ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀ

SMR .EQU H'FFFFB8 ; ｼﾘｱﾙﾓｰﾄﾞﾚｼﾞｽﾀ

BRR .EQU H'FFFFB9 ; ﾋﾞｯﾄﾚｰﾄﾚｼﾞｽﾀ

TDR .EQU H'FFFFBB ; ﾄﾗﾝｽﾐｯﾄﾃﾞｰﾀﾚｼﾞｽﾀ

SSR .EQU H'FFFFBC ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀ

TDRE .BEQU 7,SSR ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀのTDREﾋﾞｯﾄ

TE .BEQU 5,SCR ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀのTEﾋﾞｯﾄ

ADCSR .EQU H'FFFFE8 ; A/Dｺﾝﾄﾛｰﾙ/ｽﾃｰﾀｽﾚｼﾞｽﾀ

ADDRAH .EQU H'FFFFE0 ; A/DﾃﾞｰﾀﾚｼﾞｽﾀAH

ADST .BEQU 5,ADCSR ; A/Dｺﾝﾄﾛｰﾙ/ｽﾃｰﾀｽﾚｼﾞｽﾀのADSTﾋﾞｯﾄ

ADF .BEQU 7,ADCSR ; A/Dｺﾝﾄﾛｰﾙ/ｽﾃｰﾀｽﾚｼﾞｽﾀのADFﾋﾞｯﾄ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 vector　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.SECTION C,DATA,LOCATE=0

.DATA.L MAIN

.ORG H'60

.DATA.L TIM\_IN

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 main program \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.SECTION P,CODE,LOCATE=H'200

MAIN:

mov.l #H'ffff00, er7 ; ｽﾀｯｸﾎﾟｲﾝﾀの初期化

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 ｼｽﾃﾑｸﾛｯｸの設定　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'ff, r0l

mov.b r0l, @DIVCR ; ｼｽﾃﾑｸﾛｯｸφを3.125MHzに設定

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 入出力の設定　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'05, r0l

mov.b r0l, @PBDDR ; PB-0を出力、PB-1を入力

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 AD変換の設定　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'08, r0l

mov.b r0l, @ADCSR ; 単一モード　AN0使用

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 通信の設定ch1　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\* 調歩同期式ﾓｰﾄﾞ、8ﾋﾞｯﾄﾃﾞｰﾀ、ﾊﾟﾘﾃｨ付加、ﾁｪｯｸ禁止、1STOPﾋﾞｯﾄ \*\*\*

mov.b #0, r0l

mov.b r0l, @SCR ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀを0に設定

mov.b r0l, @SMR ; 通信ﾌｫｰﾏｯﾄの設定

mov.b #40, r0l

mov.b r0l, @BRR ; BRRを40に設定(2400bps)

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*　ｲﾝﾀｰﾊﾞﾙﾀｲﾏ(割り込み)ITU0の設定　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'a3, r0l

mov.b r0l, @TCR0 ; 390625Hzでｶｳﾝﾄ

mov.w #39063, r0

mov.w r0, @GRA0 ; ｺﾝﾍﾟｱ値 39063

ldc #0, CCR

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　ﾀｲﾏITU1の設定　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'a0, r0l

mov.b r0l, @TCR1 ; 3.125MHzでｶｳﾝﾄ

mov.w #3125, r0

mov.w r0, @GRA1 ; ｺﾝﾍﾟｱ値 3125

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 MAIN LOOP 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

bset #0, @PBDR ; LEDを消灯

LOOP1: btst #1, @PBDR

bne LOOP1 ; ｽｲｯﾁを押していない間、LOOP1へ

bset IMIEA0 ; ﾀｲﾏ割り込み許可

bset STR0 ; ｶｳﾝﾄ開始

bset TE ; 送信許可

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 LEDは点灯 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

LOOP2: bclr #0, @PBDR ; LEDを点灯

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 0.5秒待ちLOOP 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.w #500, r1 ; 繰り返し回数500回

bset STR1 ; ｶｳﾝﾄ開始

MS\_1: btst IMFA1

beq MS\_1 ; 1ms経つまでMS\_1へ

bclr IMFA1 ; IMFAのｸﾘｱ

sub.w #1, r1

bne MS\_1 ; r1が0になるまでMS\_1へ

bclr STR1 ; ｶｳﾝﾄ終了

mov.w #0, r1

mov.w r1, @TCNT1 ; ｶｳﾝﾀｸﾘｱ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 LEDは消灯 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

bset #0, @PBDR ; LEDを消灯

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 0.5秒待ちLOOP 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.w #500, r1 ; 繰り返し回数500回

bset STR1 ; ｶｳﾝﾄ開始

MS\_2: btst IMFA1

beq MS\_2 ; 1ms経つまでMS\_2へ

bclr IMFA1 ; IMFAのｸﾘｱ

sub.w #1, r1

bne MS\_2 ; r1が0になるまでMS\_2へ

bclr STR1 ; ｶｳﾝﾄ終了

mov.w #0, r1

mov.w r1, @TCNT1 ; ｶｳﾝﾀｸﾘｱ

bra LOOP2 ; LOOP2へ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　timer interrupt　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

TIM\_IN: ; ｲﾝﾀｰﾊﾞﾙﾀｲﾏで、割り込み周期0.1secごとに実行される命令文

bclr IMFA0 ; ｺﾝﾍﾟｱﾏｯﾁﾌﾗｸﾞのｸﾘｱ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 A/D変換　 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

bset ADST ; AD変換の開始

AD: btst ADF

beq AD ; AD変換が終了するまで、ADへ

mov.b @ADDRAH, r0l ; AD変換結果をr0lﾚｼﾞｽﾀにｺﾋﾟｰ

bclr ADF ; ADFﾋﾞｯﾄをｸﾘｱ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 ﾃﾞｰﾀの送信 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

TX: btst TDRE

beq TX ; TDRが空でないときTXへ

mov.b r0l, @TDR ; AD変換結果をTDRへ、送信実行

bclr TDRE ; TDRに有効な送信ﾃﾞｰﾀがある

rte ; 割り込み終了MAIN LOOPへ戻る

.end

＜参考＞

・モータ駆動側

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\* 訓練課題：モータ駆動プログラム　jusin.mar \*

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.CPU 300HA

PBDDR .EQU H'FFFFD4 ; ﾎﾟｰﾄBﾃﾞｰﾀﾃﾞｨﾚｸｼｮﾝﾚｼﾞｽﾀ

PBDR .EQU H'FFFFD6 ; ﾎﾟｰﾄBﾃﾞｰﾀﾚｼﾞｽﾀ

SCR .EQU H'FFFFBA ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀ

SMR .EQU H'FFFFB8 ; ｼﾘｱﾙﾓｰﾄﾞﾚｼﾞｽﾀ

BRR .EQU H'FFFFB9 ; ﾋﾞｯﾄﾚｰﾄﾚｼﾞｽﾀ

RDR .EQU H'FFFFBD ; ﾚｼｰﾌﾞﾃﾞｰﾀﾚｼﾞｽﾀ

SSR .EQU H'FFFFBC ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀ

ORER .BEQU 5,SSR ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀのORERﾋﾞｯﾄ

FER .BEQU 4,SSR ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀのFERﾋﾞｯﾄ

PER .BEQU 3,SSR ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀのPERﾋﾞｯﾄ

RDRF .BEQU 6,SSR ; ｼﾘｱﾙｽﾃｰﾀｽﾚｼﾞｽﾀのRDRFﾋﾞｯﾄ

RE .BEQU 4,SCR ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀのREﾋﾞｯﾄ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 vector　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.SECTION C,DATA,LOCATE=0

.DATA.L MAIN

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 main program \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

.SECTION P, CODE, LOCATE=H'200

MAIN:

mov.l #H'ffff00, er7 ; ｽﾀｯｸﾎﾟｲﾝﾀの初期化

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 入出力の設定　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #H'3F, r0l

mov.b r0l, @PBDDR ; PB-0～PB-5を出力

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*　 通信の設定ch1　 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;\*\*\* 調歩同期式ﾓｰﾄﾞ、8ﾋﾞｯﾄﾃﾞｰﾀ、ﾊﾟﾘﾃｨ付加、ﾁｪｯｸ禁止、1STOPﾋﾞｯﾄ \*\*\*

mov.b #0, r0l

mov.b r0l, @SCR ; ｼﾘｱﾙｺﾝﾄﾛｰﾙﾚｼﾞｽﾀを0に設定

mov.b #H'1, r0l

mov.b r0l, @SMR ; 通信ﾌｫｰﾏｯﾄの設定(φ/4)

mov.b #80, r0l

mov.b r0l, @BRR ; BRRを80に設定(2400bps)

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 時間待ち 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.w #500, r1 ; 繰り返し回数500回

WAIT: nop

nop

sub.w #1, r1

bne WAIT ; r1が0になるまでWAITへ

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* 　 MAIN LOOP 　\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #0, r0l

mov.b r0l, @PBDR ; INAとINBは0でﾓｰﾀ停止

bset RE ; 受信許可

LOOP: btst ORER

beq FER\_F ; ORERが0ならFER\_Fへ

bclr ORER

bra LOOP

FER\_F: btst FER

beq PER\_F ; FERが0ならPER\_Fへ

bclr FER

bra LOOP

PER\_F: btst PER

beq RDR\_F ; PERが0ならRDR\_Fへ

bclr PER

bra LOOP

RDR\_F: btst RDRF

beq LOOP ; RDRFが0ならLOOPへ

mov.b @RDR, r0l ; 受信ﾃﾞｰﾀをr0lﾚｼﾞｽﾀにｺﾋﾟｰ

bclr RDRF

cmp.b #127, r0l

bcs REV ; 受信ﾃﾞｰﾀが127以下のときREVへ

;\*\*\*\*\*\*\*\*\*\*\*\* 　 受信ﾃﾞｰﾀが128以上のとき(ﾓｰﾀ正転) 　 \*\*\*\*\*\*\*\*\*\*\*\*\*

mov.b #128, r0h

sub.b r0h, r0l ; 受信ﾃﾞｰﾀを0～127のﾃﾞｰﾀに変換

cmp.b #48, r0l

bls STOP ; 47以下のときSTOPへ

mov.b #8, r1l

mov.b #0, r0h

divxu.b r1l, r0 ; ﾃﾞｰﾀを8で割り、6～15の速度設定に変換

mov.b #H'10, r0h

add.b r0h, r0l ; 正転方向ﾃﾞｰﾀ（INAは1、INBは0）を付加

mov.b r0l, @PBDR ; 正転方向ﾃﾞｰﾀ＋速度設定ﾃﾞｰﾀ を出力

bra LOOP ; LOOPへ

;\*\*\*\*\*\*\*\*\*\*\*\*\* 　 受信ﾃﾞｰﾀが127以下のとき(ﾓｰﾀ逆転)　 \*\*\*\*\*\*\*\*\*\*\*\*

REV: mov.b #127, r2l

sub.b r0l, r2l ; 受信ﾃﾞｰﾀを127～0のﾃﾞｰﾀに変換

cmp.b #48, r2l

bls STOP ; 47以下のときSTOPへ

mov.b #8, r1l

mov.b #0, r2h

divxu.b r1l, r2 ; ﾃﾞｰﾀを8で割り、6～15の速度設定に変換

mov.b #H'20, r2h

add.b r2h, r2l ; 逆転方向ﾃﾞｰﾀ（INAは0、INBは1）を付加

mov.b r2l, @PBDR ; 逆転方向ﾃﾞｰﾀ＋速度設定ﾃﾞｰﾀ を出力

bra LOOP ; LOOP1へ

STOP: mov.b #0, r0l

mov.b r0l, @PBDR ; INAとINBは0、速度設定も0でﾓｰﾀ停止

bra LOOP ; LOOP1へ

.end